;================================================================
; rfide.asm - 125kHz RFID transponder emulator
;
;	(C) 2010 by Tomas Pecina
;
; Device:
; 	ATtiny85
; 
; Fuses:
; 	EFUSE = 0bXXXXXXXX
; 	HFUSE = 0b1XX1XXXX
;	LFUSE = 0b01XX0010
; 	(X = don't care)
	
.nolist
.include "tn85def.inc"
.include "main.inc"
.list

; constants
	.equ	tc1 = 6
	.equ	tc2 = 13
	.equ	tc3 = 72
	.equ	tc4 = 61
	.equ	tc5 = 200
	.equ	tc6 = 44
	.equ	tc7 = 92
	.equ	tc11 = 200

; pins
	.equ	LED = PB4
	.equ	BTN = PB1
	.equ	RI = PB3
	.equ	RP = PB2
	.equ	EO = PB0
	
; blink
	.equ	BLRATE = 35
	.equ	BLRDY = 0b11111

; register variables
	.def	tmr1 = r0
	.def	sreg1 = r1
	
; data
	.dseg
	.org	SRAM_START
buf:
	.byte	8

; EEPROM
	.eseg
	.org	0
rfidee:
	.byte	8
	
; vectors
	.cseg

	.org	0
	rjmp	start

	.org	PCI0addr
	rjmp	pcint

	.org	OVF1addr
	rjmp	ovf1int

start:
; disable interrupts
	cli

; initialize SP
	ldiw	A, RAMEND
	out	SPH, AH
	out	SPL, AL

; enable WDT
	wdr
	in	AL, MCUSR
	cbr	AL, (1<<WDRF)
	out	MCUSR, AL
	in	AL, WDTCR
	sbr	AL, (1<<WDCE) | (1<<WDE)
	out	WDTCR, AL
 	ldi	AL, (1<<WDE) | (1<<WDP3)
	out	WDTCR, AL

; initialize hardware
	rcall	tmrinit
	ldi	AL, (1<<LED) | (1<<RP) | (1<<EO)		; output on LED, RP & EO
	out	DDRB, AL
	ldi	AL, (1<<BTN) | (1<<RI) | (1<<RP) | (1<<EO)	; pull-ups on BTN & RI, RP & EO to high
	out	PORTB, AL

; enable interrupts
	sei

; setup TC/1 for time measurement
	ldi	AL, 0b00001111
	out	TCCR1, AL
	ldi	AL, 0b00000010
	out	GTCCR, AL
	clr	AL
	out	TCNT1, AL
	ldi	AL, tc4
	out	OCR1A, AL
	in	AL, TIFR
	sbr	AL, (1<<OCF1A)
	out	TIFR, AL

; debounce
	rcall	debounce

; check press type
	in	AL, TIFR
	sbrc	AL, OCF1A
s7:	rjmp	longpress

; send code until button pressed or timeout
shortpress:
	ldiw	X, buf 		; get code from EEPROM
	ldiw	Y, rfidee
	ldi	BL, 8
s1:	rcall	readeeprom
	st	X+, AL
	adiw	Y, 1
	dec	BL
	brne	s1
	rcall	chkbuf 		; valid code?
	brts	s7		; no, start reader mode
	ldiw	A, BLRDY 	; blink once
	rcall	blink
	rcall	mtinit		; initialize master (timeout) timer
	rcall	tmrstart	; get TC/0 running
s2:	wdr
	in	AL, TCNT1 	; blink LED according to TC/1
	andi	AL, 0b111111
	cbi	PORTB, LED
	brne	s9
	sbi	PORTB, LED	
s9:	ldiw	X, buf
	ldi	BH, 8
s4:	ld	AH, X+
	ldi	BL, 8
s3:	in	AL, TCNT0
	sbrs	AL, 5 		; rising edge?
	rjmp	s3
	rcall	s8
s5:	in	AL, TCNT0
	sbrc	AL, 5 		; falling edge?
	rjmp	s5
	rcall	s8
	lsr	AH
	dec	BL
	brne	s3
	dec	BH
	brne	s4
	tst	tmr1 		; timeout?
	breq	tosleep
	in	AL, PINB
	sbrs	AL, BTN		; button pressed?
	rjmp	dbnslp
	rjmp	s2
s8:	bst	AL, 5 		; copy TC/0 bit corresponding to 256us to T
	bld	AL, 0
	eor	AL, AH 		; modulate with data bit and transmit
	sbrs	AL, 0
	rjmp	s6
	sbi	PORTB, EO
	ret
s6:	cbi	PORTB, EO
	ret
	
; debounce and go to sleep
dbnslp:
	ldi	AL, (1<<BTN) | (1<<RI) | (1<<RP) | (1<<EO)	; pull-ups on BTN & RI, RP & EO to high
	out	PORTB, AL
	rcall	debounce
	
; go to sleep
tosleep:
	ldi	AL, (1<<BTN) | (1<<RI) | (1<<RP) | (1<<EO)	; pull-ups on BTN & RI, RP & EO to high
	out	PORTB, AL

; stop timers/counters
	clr	AL
	out	TCCR0B, AL
	out	TCCR1, AL
	
; disable WDT
	wdr
	in	AL, MCUSR
	cbr	AL, (1<<WDRF)
	out	MCUSR, AL
	in	AL, WDTCR
	sbr	AL, (1<<WDCE) | (1<<WDE)
	out	WDTCR, AL
	cbr	AL, (1<<WDCE) | (1<<WDE)
	out	WDTCR, AL

; set pins to power saving mode
	ldi	AL, (1<<LED) | (1<<RP) | (1<<EO)	; output on LED, RP & EO
	out	DDRB, AL
	ldi	AL, (1<<BTN) | (1<<RP) | (1<<EO)	; pull-up on BTN, RP & EO to high
	out	PORTB, AL

; enable interrupt on PCINT1
	in	AL, GIFR
	sbr	AL, (1<<PCIF)
	out	GIFR, AL
	sbi	PCMSK, PCINT1
	in	AL, GIMSK
	sbr	AL, (1<<PCIE)
	out	GIMSK, AL

; enable sleep & go to power-down sleep
	in	AL, PRR
	sbr	AL, (1<<PRTIM1) | (1<<PRTIM0) | (1<<PRUSI) | (1<<PRADC)
	out	PRR, AL
	in	AL, MCUCR
	andi	AL, (1<<SE) | (1<<SM1) | (1<<SM0)
	ori	AL, (1<<SE) | (1<<SM1)
	out	MCUCR, AL
	sleep

; wake up
	in	AL, PRR
	cbr	AL, (1<<PRTIM1) | (1<<PRTIM0) 		; re-enable timers
	out	PRR, AL
	rjmp	start

; button interrupt
pcint:
	in	AL, GIMSK 	; disable interrupt
	cbr	AL, (1<<PCIE)
	out	GIMSK, AL
	reti

; read code
longpress:
	rcall	mtinit 		; initialize master (timeout) timer
	sbi	PORTB, LED	; LED and power on
	cbi	PORTB, RP
l10:	ldiw	X, buf 		; prepare buf and AH for data
	ser	AL
	st	X+, AL
	ldi	AH, 0b11000000
l1:	wdr
	in	BL, PINB
	rcall	tmrstart
	ldi	AL, tc6
	rcall	tmrprep
l2:	tst	tmr1 		; timeout?
	breq	tosleep
	in	AL, PINB
	sbrs	AL, BTN		; button pressed?
	rjmp	dbnslp
	eor	AL, BL
	sbrc	AL, RI 		; change of RI?
	rjmp	l1		; yes, restart
	in	AL, TIFR
	sbrs	AL, OCF0A
	rjmp	l2
l3:	tst	tmr1 		; timeout?
	breq	m13
	in	AL, PINB
	sbrs	AL, BTN 	; button pressed?
	rjmp	dbnslp
	eor	AL, BL
	sbrs	AL, RI 		; change of RI?
	rjmp	l3		; no, wait
	rcall	tmrstart	; edge detected, start timer
l6:	wdr
	ldi	BH, 9		; nine 1's needed
	sbrc	BL, RI
	dec	BH 		; we already have one, eight 1's will do
l7:	tst	tmr1		; timeout?
	breq	m13
	in	AL, PINB
	sbrs	AL, BTN 	; button pressed?
	rjmp	dbnslp
	rcall	rin 		; get bit
	brts	l1		; if error resync
	sbrs	BL, RI		; zero?
	rjmp	l6		; start over
	dec	BH
	brne	l7
	ldi	BH, (64-9) 	; 64-9 more bits needed
l8:	rcall	rin		; get bit
	brts	l1		; if error resync
	bst	BL, RI		
	ror	AH
	bld	AH, 7 		; store bit
	brcc	l9		; byte full?
	st	X+, AH
	ldi	AH, 0b10000000
l9:	dec	BH
	brne	l8
	rcall	chkbuf 		; check buf for integrity
	brts	l10		; if error resync
	cbi	PORTB, LED 	; LED and reader off
	sbi	PORTB, RP
	ldiw	X, buf		; check if EEPROM write is required
	ldiw	Y, rfidee
	ldi	BL, 8
m9:	rcall	readeeprom
	ld	BH, X+
	cp	AL, BH
	brne	m10
	adiw	Y, 1
	dec	BL
	brne	m9
m13:	rjmp	tosleep		; no, proceed
m10:	ldiw	X, buf		; write to EEPROM
	ldiw	Y, rfidee
	ldi	BL, 8
m12:	ld	AL, X+
	rcall	writeeeprom
	adiw	Y, 1
	dec	BL
	brne	m12
	rjmp	tosleep
	
; get bit
rin:	clt
	ldi	AL, tc6
	rcall	tmrwait
	in	BL, PINB
	ldi	AL, tc7
	rcall	tmrprep
l5:	in	AL, PINB
	eor	AL, BL
	sbrc	AL, RI
	rjmp	tmrstart
	in	AL, TIFR
	sbrs	AL, OCF0A
	rjmp	l5
	set
	ret

; setup TC/1 for master timeout
mtinit:
	ldi	AL, 0b00001111
	out	TCCR1, AL
	ldi	AL, 0b00000010
	out	GTCCR, AL
	clr	AL
	out	TCNT1, AL
	in	AL, TIMSK
	sbr	AL, (1<<TOIE1)
	out	TIMSK, AL
	ldi	AL, tc3
	mov	tmr1, AL
	ret

; TC/1 timer interrupt
ovf1int:
	lds	sreg1, SREG
	dec	tmr1
	sts	SREG, sreg1
	reti

; debounce ca 200ms
debounce:	
	rcall	tmrstart
m3:	ldi	BL, tc5
m1:	sbis	PINB, BTN
	rjmp	m3
	in	AH, TCNT0
m2:	in	AL, TCNT0
	eor	AL, AH
	sbrs	AL, 7
	rjmp	m2
	dec	BL
	brne	m1
	ret

; check code in buf
chkbuf:
	ldiw	X, buf
	ldi	AH, 1
	ldi	BL, 9		; check header
c1:	rcall	c2
	brtc	c5
	dec	BL
	brne	c1
	ldi	BH, 10		; check payload
	clr	DH
c7:	clr	CH
	clr	DL
	ldi	CL, 5
c6:	rcall	c2
	lsr	CH
	bld	CH, 4
	eor	DL, CH
	dec	CL
	brne	c6
	sbrc	DL, 4
	rjmp	c5
	eor	DH, CH
	dec	BH
	brne	c7
	clr	CH		; check parity
	ldi	CL, 4
c8:	rcall	c2
	lsr	CH
	bld	CH, 3
	dec	CL
	brne	c8
	cbr	DH, (1<<4)
	eor	DH, CH
	brne	c5
	rjmp	c2		; check stopbit
c5:	set
	ret
c2:	ld	AL, X
	and	AL, AH
	set
	brne	c3
	clt
c3:	lsl	AH
	brne	c4
	adiw	X, 1
	ldi	AH, 1
c4:	ret

; blink pattern in AX
blink:
b1:	mov	BL, AL
	or	BL, AH
	brne	b4
	cbi	PORTB, LED
	ret
b4:	clc
	ror	AH
	ror	AL
	cbi	PORTB, LED
	brcc	b2
	sbi	PORTB, LED
b2:	push	AL
	ldi	BL, BLRATE
b3:	rcall	tmrstart
	ldi	AL, tc11
	rcall	tmrwait
	dec	BL
	brne	b3
	pop	AL
	rjmp	b1

; initialize timer
tmrinit:
	clr	AL
	out	TCCR0A, AL
	ldi	AL, 2
	out	TCCR0B, AL
	ret

; start timing
tmrstart:
	clr	AL
	out	TCNT0, AL
	ret

; wait until AL * 8us
tmrwait:
	out	OCR0A, AL
	in	AL, TIFR
	sbr	AL, (1<<OCF0A)
	out	TIFR, AL
t1:	in	AL, TIFR
	sbrs	AL, OCF0A
	rjmp	t1
	ret

; initialize timer and return
tmrprep:
	out	OCR0A, AL
	in	AL, TIFR
	sbr	AL, (1<<OCF0A)
	out	TIFR, AL
	ret

; read byte from eeprom
readeeprom:
	sbic	EECR, EEPE
	rjmp	readeeprom
	out	EEARH, YH
	out	EEARL, YL
	sbi	EECR, EERE
	in	AL, EEDR
	ret

; write byte to  eeprom
writeeeprom:
	sbic	EECR, EEPE
	rjmp	writeeeprom
	push	AL
	clr	AL
	out	EECR, AL
	pop	AL
	out	EEARH, YH
	out	EEARL, YL
	out	EEDR, AL
	in	AL, SREG
	cli
	sbi	EECR, EEMPE
	sbi	EECR, EEPE
	out	SREG, AL
	ret